Solomon » VB.NET

DateTimePicker – reset focus

Solomon — Fri, 05 Mar 2010 03:54:18 +0000

Code Snippet – C#

        private void dateTimePicker1_Enter(object sender, EventArgs e)
        {
            DateTimePickerFormat fmt = dateTimePicker1.Format;

            dateTimePicker1.Format = DateTimePickerFormat.Long;
            dateTimePicker1.Format = DateTimePickerFormat.Custom;
            dateTimePicker1.Format = fmt;
        }

Code Snippet - VB.NET


    Private Sub DateTimePicker1_Enter(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles DateTimePicker1.Enter
        Dim fmt As DateTimePickerFormat = DateTimePicker1.Format

        DateTimePicker1.Format = DateTimePickerFormat.Long
        DateTimePicker1.Format = DateTimePickerFormat.Custom
        DateTimePicker1.Format = fmt
    End Sub

Auto Complete ComboBox – VB.NET Windows Forms

Solomon — Tue, 24 Feb 2009 04:40:15 +0000

Introduction

This is a simple code snippet which is used to make an Auto Complete ComboBox.

Using the code

Usage: Call the subroutine from within the ComboBox’s KeyPress event handler.


AutoComplete(ByRef cb As ComboBox, ByVal e As System.Windows.Forms.KeyPressEventArgs, Optional ByVal blnLimitToList As Boolean = False)

cb – ComboBox used to make the Auto Complete ComboBox.
e – System.Windows.Forms.KeyPressEventArgs used to handle the keyboard inputs.
blnLimitToList – Optional Boolean value indicating whether the user input is limited to the list values or not.

Code


    ' AutoComplete
    Public Sub AutoComplete(ByRef cb As ComboBox, ByVal e As System.Windows.Forms.KeyPressEventArgs, Optional ByVal blnLimitToList As Boolean = False)
        Dim strFindStr As String

        If e.KeyChar = Chr(8) Then  'Backspace
            If cb.SelectionStart <= 1 Then
                cb.Text = ""
                Exit Sub
            End If
            If cb.SelectionLength = 0 Then
                strFindStr = cb.Text.Substring(0, cb.Text.Length - 1)
            Else
                strFindStr = cb.Text.Substring(0, cb.SelectionStart - 1)
            End If
        Else
            If cb.SelectionLength = 0 Then
                strFindStr = cb.Text & e.KeyChar
            Else
                strFindStr = cb.Text.Substring(0, cb.SelectionStart) & e.KeyChar
            End If
        End If

        Dim intIdx As Integer = -1

        ' Search the string in the Combo Box List.
        intIdx = cb.FindString(strFindStr)

        If intIdx <> -1 Then ' String found in the List.
            cb.SelectedText = ""
            cb.SelectedIndex = intIdx
            cb.SelectionStart = strFindStr.Length
            cb.SelectionLength = cb.Text.Length
            e.Handled = True
        Else
            If blnLimitToList = True Then
                e.Handled = True
            Else
                e.Handled = False
            End If
        End If
    End Sub

History

Released on July 30^th, 2005.

Storing and retrieving Images from Access database using VB.Net

Solomon — Tue, 24 Feb 2009 04:12:05 +0000

Introduction

This is a simple code snippet which is used to store and retrieve images from Access database using VB.net.

Code


    Private Sub ShowDetails()
        Try
            Dim cn As New OleDb.OleDbConnection
            Dim cmd As OleDb.OleDbCommand
            Dim dr As OleDb.OleDbDataReader

            cn.ConnectionString = mstrConnection
            cn.Open()

            cmd = cn.CreateCommand()
            cmd.CommandText = "SELECT I_Image FROM tblImage WHERE I_Name = '" & cbI_Name.Text & "'"

            dr = cmd.ExecuteReader

            If dr.Read Then
                Dim bytImage() As Byte

                Try
                    bytImage = CType(dr(0), Byte())
                    Dim ms As New System.IO.MemoryStream(bytImage)
                    Dim bmImage As New Bitmap(ms)
                    ms.Close()

                    pbI_Image.Image = bmImage
                    pbI_Image.Refresh()
                Catch ex As Exception
                    MsgBox(ex.ToString)
                End Try
            End If

            dr.Close()
            cn.Close()

            cmd.Dispose()
            cn.Dispose()
        Catch ex As Exception
            MsgBox(ex.ToString)
        End Try
    End Sub

    Private Sub SaveData()
        Try
            Dim cn As New OleDb.OleDbConnection
            Dim cmd As OleDb.OleDbCommand

            cn.ConnectionString = mstrConnection
            cn.Open()

            cmd = cn.CreateCommand()

            If mstrFlag = "N" Then
                cmd.CommandText = "INSERT INTO tblImage VALUES (@I_Name, @I_Image)"
            ElseIf mstrFlag = "M" Then
                cmd.CommandText = "UPDATE tblImage SET I_Name = @I_Name, I_Image = @I_Image WHERE I_Name = '" & cbI_Name.Tag.ToString & "'"
            End If

            Dim bytImage() As Byte

            Try
                Dim ms As New System.IO.MemoryStream
                Dim bmpImage As New Bitmap(pbI_Image.Image)

                bmpImage.Save(ms, System.Drawing.Imaging.ImageFormat.Jpeg)
                bytImage = ms.ToArray()
                ms.Close()
            Catch ex As Exception
                MsgBox(ex.ToString)
            End Try

            cmd.Parameters.Add(New OleDb.OleDbParameter("@I_Name", OleDb.OleDbType.VarChar, 120))
            cmd.Parameters.Add(New OleDb.OleDbParameter("@I_Image", OleDb.OleDbType.Binary))
            cmd.Parameters("@I_Name").Value = cbI_Name.Text
            cmd.Parameters("@I_Image").Value = bytImage

            If cmd.ExecuteNonQuery() > 0 Then
                MsgBox("Record has been " & IIf(mstrFlag = "N", "added", "modified").ToString & " successfully.", MsgBoxStyle.Information)
            End If

            cmd.Dispose()
            cn.Dispose()
        Catch ex As Exception
            MsgBox(ex.ToString)
        End Try

        FillData()
    End Sub